Crie seu próprio ticker de notícias Bluetooth

Colocado sobre 2017-11-13

Exemplo de ticker de notícias

Suprimentos

Arduino Uno R3 - clone Em estoque Ou um Arduino Nano € 11,70 Módulo matricial MAX7219 4x Fora de estoque Este é o display, você precisa de pelo menos 1, 2 é ainda melhor! € 10,35 Módulo Bluetooth HC-06 com adaptador - clone Em estoque Este é o Escravo Bluetooth HC-06, você precisa de 1 € 8,60 Resistor de filme metálico 5,6KΩ 1/4W - 100 peças Fora de estoque O divisor de tensão para o módulo Bluetooth € 1,45 Resistor de filme metálico 10KΩ 1/4W - 10 peças Em estoque O divisor de tensão para o módulo Bluetooth € 1,80 Fonte de alimentação Mean Well SGA12E09-P1J - 9V 1,33A Em estoque Para energia extra, USB não pode fornecer energia suficiente € 14,25 Soquete DC embutido 5,5 mm x 2,1 mm - 5 peças Em estoque € 2,50 Total € 50,65

O horário:

O esquema mostra como tudo deve ser conectado. Se você já sente a fiação de todos esses fios, não olhe muito para o todo, mas tente considerar e conectar os módulos um a um. Você verá que não é tão ruim.

O esquema mostra apenas um módulo de LED matricial quádruplo, na realidade você pode ligar dois juntos para uma largura dupla!

Diagrama de conexão do quadro de mensagens

O módulo bluetooth requer um pouco de atenção extra. Os sinais de comunicação Bluetooth (TX e RX) funcionam em 3,3 volts, enquanto o Arduino trabalha com 5 volts. Os dois resistores reduzirão os 5 volts do Arduino para cerca de 3,3 volts.

A nutrição:
Você pode ver que uma fonte de alimentação de 5 volts é usada. Você tem que. Um Arduino conectado a USB não pode fornecer corrente suficiente para alimentar a matriz de LED, especialmente com uma matriz dupla.

Biblioteca e esboço Arduino :

O sketch Arduino utiliza duas bibliotecas externas, para instalar estas, procure por MD_MAX72xx no gerenciador de bibliotecas. Em seguida, instale MD_Max72xx e MD_Parola

Biblioteca Arduino Ticker USB

Defina o módulo correto:
Após a instalação das bibliotecas, precisamos informar à biblioteca MD_Max72xx qual módulo de matriz de leds estamos utilizando.

Localize o arquivo em seu disco rígido: MD_MAX72xx.h
(provavelmente na pasta C:\Usuários\seu nome\Documentos\ Arduino \libraries\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

O esboço Arduino :

Então agora podemos carregar o esboço.
Copie o esboço e cole o código no software Arduino , selecione a porta COM correta, digite Arduino e pressione upload!

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

Se tudo estiver bem (e por que não?) você verá a mensagem “Olá, envie uma nova mensagem por bluetooth”. Então está na hora de instalar o App Android no seu celular e enviar uma nova mensagem via Bluetooth!

O aplicativo Android:

Para alterar o texto no ticker de notícias, precisamos de um programa de terminal Bluetooth, por exemplo, o Serial Bluetooth Terminal de Kai Morich, através do Loja de aplicativos.

SerialBluetoothTerminal

O funcionamento do App é bastante autoexplicativo, mas no vídeo mostro passo a passo.

terminal bluetooth

Atenção: o iOS da Apple não pode se conectar ao módulo bluetooth usado, então isso só funciona com dispositivos Android.

Assista o vídeo

Ainda há ambiguidades? Você pode ver tudo mais de perto neste vídeo.

postado por Bart Venneker Local na rede Internet | Youtube Bart Venneker é um entusiasta de eletrônica e faz vídeos educativos sobre eletrônica, Arduino e impressoras 3D.

Comentários

Ad Laat

Infelizmente, os ajustes na biblioteca não podem ser encontrados, o que significa que o ticker não funciona, que pena! Uma versão diferente poderia ter sido usada? Saudações, Ad de Laat

Colocado sobre 19 novembro 2023

