Arduino Leonardo - Fechadura Eletrônica

Colocado sobre 2020-06-22

Falha no código na memória EEPROM

Agora podemos obter um código, verificá-lo, mas que tal salvá-lo. Porque quando você reseta o Arduino a RAM é limpa, então temos que encontrar outra forma de armazená-la e poder alterá-la sem ter que recarregar o programa. É aqui que entra a EEPROM no jogo...

Portanto, temos que usar a biblioteca EEPROM.

Storing and Getting the code from EEPROM

#include <EEPROM.h>

unsigned char Eeprom_PasscodeLength = 0;

void GetEepromCode() {
   EEPROM.get(0, Eeprom_PasscodeLength);
   if (Eeprom_PasscodeLength) {
      NewPasscodeLength = Eeprom_PasscodeLength;
      for (unsigned char i = 0; i < Eeprom_PasscodeLength; i++) {
        EEPROM.get(i + 1, Master[i]);
      }
   }
   else {
    NewPasscodeLength = PasscodeLength;
    return;
   }
   PasscodeLength = NewPasscodeLength;
}

void WriteEepromCode(){
  EEPROM.put(0, PasscodeLength);
  for (unsigned char i = 0; i < PasscodeLength; i++) {
    EEPROM.put(i + 1, Master[i]);
  }
}

Agora que podemos armazenar e obter um código da EEPROM, é hora de habilitá-lo para alterar o código enquanto o programa ainda está sendo executado no Arduino .

Changing the code while the program is running

void CheckNewCode() {
  if (EnableDebug) {
    Serial.print("dataCountBuff1: ");
    Serial.println(dataCountBuff1);
    Serial.print("dataCountBuff2: ");
    Serial.println(dataCountBuff2);
    Serial.print("codeBuff1: ");
    Serial.println(code_buff1);
    Serial.print("codeBuff2: ");
    Serial.println(code_buff2);
  }  
  if (dataCountBuff1 == dataCountBuff2) {
      if(!strcmp(code_buff1, code_buff2)){
          NewPasscodeLength = dataCountBuff2;
          for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
            Master[i] = 0;
          }
          
          for (unsigned char i = 0; i <= NewPasscodeLength; i++) {
            Master[i] = code_buff1[i];
          }

          if (EnableDebug) {
            Serial.println();
            Serial.print("Master: ");
            Serial.println(Master);
          }
          lcd.clear();
          lcd.print("Passcodes Match");
          _delay_ms(1000);
          lcd.clear();
        }
     else {
        NewPasscodeLength = PasscodeLength;
        lcd.clear();
        lcd.setCursor(0,0);
        lcd.print("Codes do not match");
        if (EnableDebug) {
          Serial.println();
          Serial.println("Passcodes do not match");
        }
        _delay_ms(1000);
        lcd.clear();
     }
  }
  else {
    NewPasscodeLength = PasscodeLength;
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Codes do not match");
    if (EnableDebug) {
      Serial.println();
      Serial.println("Passcodes are not the same length");
    }
    _delay_ms(1000);
    lcd.clear();
  }
  clearData();
}

void ChangeCode() {
    dataCountBuff1 = 0;
    dataCountBuff2 = 0;
    for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
      code_buff1[i] = 0;
      code_buff2[i] = 0;
    }
    if (EnableDebug) {
      Serial.println();
      Serial.println("Changing Master");
    }
    lcd.clear();
    lcd.print("Enter new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while(Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff1 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff1[i] = Data[i];
    }
    clearData();
    lcd.clear();
    _delay_ms(500);
    lcd.print("Confirm new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while (Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff2 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff2[i] = Data[i];
    }
    clearData();
    CheckNewCode();
    PasscodeLength = NewPasscodeLength;
    if (EnableDebug) {
      Serial.print("PasscodeLength: ");
      Serial.println(PasscodeLength);
    }
    WriteEepromCode();
}

Página anterior 8. O código - parte 3 - O código Pagina atual 9. O código - parte 4 - Mais códigos Próxima página 10. O código - parte 5 - Configuração e Loop 1. Introdução 2. O Esquema 3. O Teclado 4. O módulo LCD 5. o servo 6. O código - parte 1 - O teclado 7. O código - parte 2 - O LCD 8. O código - parte 3 - O código 9. O código - parte 4 - Mais códigos 10. O código - parte 5 - Configuração e Loop 11. o código completo postado por Sander Speetjens

Arduino Leonardo - Fechadura Eletrônica

Falha no código na memória EEPROM

Storing and Getting the code from EEPROM

Changing the code while the program is running

Comentários