Sempre pontual com os módulos de relógio de tempo REAL DS1307 e DS3231

Colocado sobre 2016-07-16

Módulos de relógio de tempo REAL

Versões do relógio de tempo REAL

A série de relógios de tempo REAL contém muitos números de tipos diferentes, todos com funcionalidade comparável. Nesta série, apenas 2 versões são 'mainstream', ou seja, o DS1307 e a DS3231. Esses chips têm a opção de conectar uma bateria e possuem um pino de saída sqw, com o qual o controlador pode receber um pulso de clock de (1Hz, 1.024kHz, 4.096kHz, 8.192kHz). Ambos os CIs também possuem uma interface One-Wire, que possibilita conectá-los por I²para atender C.

DS1302 Módulo Relógio em Tempo Real - SPIO módulo de relógio em tempo real DS1302 possui uma interface SPI através da qual ele pode contar as horas. Em estoque € 1,90

Módulo de relógio de tempo REAL DS3231Módulo de relógio de tempo REAL com chip DS3231. Este módulo garante que o Arduino saiba a hora exata o tempo todo. Ao conectar o Arduino ao pino 'sqw', é possível gerar uma interrupção a cada segundo com a qual os valores do sensor ou um display podem ser endereçados. Em estoque € 4,05

Conectando o módulo RTC ao Arduino UNO

Os módulos RTC vêm em diferentes formas e tamanhos, mas a conexão com o Arduino é a mesma para todos os módulos. O módulo deve, em qualquer caso, ser alimentado com 5V, além disso, a interface I2C deverá ser conectada aos pinos SDA (dados seriais) SCL (relógio serial) do Arduino (são os pinos A4 e A5 do Arduino UNO). Além disso, a saída SQW pode ser conectada a qualquer pino do Arduino para receber um pulso de clock do RTC.

Conexão DS1307 Arduino UNO

Código BC

Os valores numéricos nos chips RTC são armazenados no formato BCD. O código BCD é mais fácil de usar do que números decimais em nível de hardware, mas esses códigos não são muito úteis em software. Os números de e para o chip devem, portanto, ser codificados e decodificados para que o controlador e o RTC se entendam.

// Convert decimal to BCD
byte decToBcd(byte val)
{
  return( (val/10*16) + (val%10) );
}
//Convert BCD to decimal
byte bcdToDec(byte val)
{
  return( (val/16*10) + (val%16) );
}

Escreva a hora atual no RTC

A hora só precisa ser escrita no RTC uma vez quando ele estiver conectado à bateria. O próprio RTC mantém o tempo e continua contando, mesmo quando não está conectado ao controlador.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setDS3231time(
    byte second, 
    byte minute, 
    byte hour, 
    byte dayOfWeek, 
    byte dayOfMonth, 
    byte month, 
    byte year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //set next input to start at the seconds register
  Wire.write(0); 
  
  //set seconds
  Wire.write(decToBcd(second)); 
  //set minutes
  Wire.write(decToBcd(minute)); 
  //set hours
  Wire.write(decToBcd(hour)); 
  //set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfWeek));  
  //set date (1 to 31)
  Wire.write(decToBcd(dayOfMonth)); 
  //set month
  Wire.write(decToBcd(month));
  //set year 20(0 to 99)
  Wire.write(decToBcd(year)); 
    
  Wire.endTransmission();
}

Relógio do disco rígido

De tijd van de RTC lezen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void readDS3231time(
    byte *second,
	byte *minute,
	byte *hour,
	byte *dayOfWeek,
	byte *dayOfMonth,
	byte *month,
	byte *year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  //set DS3231 register pointer to 00h
  Wire.write(0); 
  Wire.endTransmission();
      
  //request seven bytes of data from DS3231
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

Mostrar a hora

Com essas funções juntas, o tempo pode ser determinado pelo Arduino . Com a função abaixo, esses dados são gravados no monitor serial, mas as possibilidades de exibir a hora são infinitas.

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  //set the initial time (only once, not every startup)
  //seconds, minutes, hours, dayofweek, day, month, year
  //11:00:00, Saturday, 2016-07-16
  setDS3231time(00,00,11,7,16,7,16);
}

void displayTime()
{
  byte second, minute, hour; 
  byte dayOfWeek, dayOfMonth, month, year;
  
  //retrieve data
  readDS3231time(&second, &minute, &hour, &dayOfWeek, 				     &dayOfMonth, &month, &year);
    
  //Hour
  Serial.print(hour, DEC);
  Serial.print(":");
  //Minute (+0 if needed)
  if (minute<10)
  {
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  //Second (+0 if needed)
  if (second<10)
  {
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
    
  //Day
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  //Month
  Serial.print(month, DEC);
  Serial.print("/");
  //Year
  Serial.print(year, DEC);
}


void loop()
{
  displayTime(); 
  delay(1000);
}

SQW frequentie instellen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //move pointer to SQW address
  Wire.write(0x07); 
 
  //set output clock speed
  //0x00 = Off
  //0x10 = 1Hz
  //0x11 = 4.096Hz
  //0x12 = 8.192Hz
  //0x13 = 32.768Hz
  Wire.write(0x10);
 
  Wire.endTransmission();  
}

Com este código pode ser construído um relógio completo, que pode exibir a hora. Isso pode ser feito em um display de 7 segmentos, como um relógio analógico, com sinais de fumaça ou ainda pode ser falado quando solicitado. Além disso, o horário também pode ser aproveitado na domótica / domótica, a cafeteira liga às 8h da manhã, o micro-ondas às 17h15 da tarde e as cortinas fecham às 19h01h05. Tudo é possível.

postado por Robin Blok Local na rede Internet Me interesso por eletrônica, programação e principalmente a combinação entre elas. Para Opencircuit , escrevo blogs nos quais explico como a eletrônica e os módulos funcionam.